Set

Set-cmd

Brief Introduction

Change the attributes of the specified dataset, data plot, or worksheet.

Syntax

set name [option] [value];

Specifying Worksheet, Dataset or Data Plot

We usually specify worksheet, dataset or data plot by name.

• If name is a worksheet, all datasets on the worksheet are affected.
• If name is a dataset or data plot, only that dataset or data plot is affected.

As of Origin 2017, name can refer to multiple plots of the same worksheet dataset, using a Book_N:n syntax. For the following example, create Book1 and fill columns A and B with row numbers in rows 1 - 32: plotxy iy:=(1,2)[1:16] plot:=201 color:=1; // creates a scatter plot %A = %H; // puts the active window title into %A win -a Book1; // activates Book1 plotxy iy:=(1,2)[17:32] plot:=201 color:=2 ogl:=[%A]1!; // adds plot 2 to the graph and sets color to red win -a Graph1; // activates Graph1 set Book1_B -z 24; // changes symbol size of plot 1 to 24; set Book1_B:2 -z 24; // changes symbol size of plot 2 to 24

Specifying Data Point

We can specify the data point by providing a number after the dataset name. For example:

set %C 13 -c 2;    //This sets the color of 13th datapoint to Red

Specifying Pattern

From Origin 2017 SR1, if you want to set the pattern properties for a multiple pattern plot, you can specify the pattern index after “p” in option directly. That is to say, p is the first pattern, p2 is the second pattern, p3 is the third pattern and etc.For example:

set %C -pf 1; // Turn on '''Fill Area Under Curve''' option
set %C -pfv 9;// Set to '''Fill to next data plot – Above Below Colors'''
set %C -pfb 2; // Set the fill color of “Pattern Above”
set %C -p2fb 3; // Set the fill color of “Pattern Below”

Options

The option switch determines which attribute is set to value. (Read these attributes with the get command.) Some of the values have a built-in list in Origin (color, shape, etc.), user can use the index number to complete the set, indicated by value#.

Option for Columns

Option for Data Plots

Option for Symbols

Option for Lines

Option for Text Labels

Option for Bar and Column Plots

Option for Error Bars

Option for Data Plot Labels

Option for Transparency

Other Options

Example

Example 1

The following script sets the beginning of the display range for col(B) to 10.

range rr = [Book1]Sheet1!B; 
set rr -b 10;

Example 2

The next script sets the line width to 2 pts.

//set the line width of 2nd plot on graph to be 2pts
range rr = !2; 
set rr -w 1000;

Example 3

The next script hides data plot from col(B) in graph.

range rr = [Book1]Sheet1!B; 
set rr -s 0;

Example 4

The following script opens the Plot Details dialog box correspond to active data plot.

set %C;

Example 5

The next script sets the active scatter data plot to display row numbers as data point symbols.

set %C -k 11;

Example 6

The next script adds an XY data plot (col(B) in Book2 sheet1 as Y, col(A) in Book1 sheet1 as X) to the active layer.

range r1 = [Book2]Sheet1!B;
range r2 = [Book1]Sheet1!A;
layer -i r1;
set r2 -x r1;
rescale;

Example 7

In this example, open a new project and import the WIND.DAT file from the Samples\Graphing\ folder. Select the Month column and then move to Last. Set this column as a label column. Select the Power and Month column and select Plot:Scatter. Then run the following script to set the label data plot display attributes.

ii = font(Arial);
//use font function to find Arial index #
range rr = [Wind]Wind!A;
set rr -tr 90;  //rotate 90 degrees
set rr -ty 50;  //50% y offset
set rr -tj 0;  //left justify
set rr -tf ii;  //set as Arial font

Example 8

In this example, we first plot a XY line and then add some other dataset into the graph. Then give each dataset different settings.

newbook; //New a workbook
string wname$ = page.name$; //Get new workbook's name
wks.ncols=10; //Set column numbers to be 10
int nn = wks.ncols;
csetvalue formula:="i-1" col:=1;
Loop(ii, 2, nn)
{
 csetvalue formula:="(i-1)/(2/(ii-1))" col:=$(ii);
}; //Gave every column values
set %c -em 10; //Only display 10 values
plotxy iy:=(1,2) plot:=201; //Plot a scatter graph with first 2 columns
for(jj=3; jj<=nn; jj++)
{
 range rr = [%(wname$)]sheet1!col($(jj));
 string bb$ = %(nameof(rr)$); //change dataset name
 layer -i201 %(bb$); //add new plot to the same layer
}; 
int tt = 3;
repeat 8
{
 int tt2 = 1+mod(tt,3);
 range rr = $(tt-1);
 set rr -c $(tt-1); //set symbol color

 set rr -z $(9+(tt-2)); //set symbol size
 set rr -k $(tt2); //set symbol type
 tt++;
};
rescale;

Example 9

In this example, we first plot a XY scatter, set it to be colormapped and then add some other dataset into the graph. Useing the first plot's setting values to modify the others.

Newbook;
string wname$ = page.name$; // Get workbook name
wks.ncols = 5; // Set number of coiumn to be 5
int nn = wks.ncols;
col(1) = {2000:2010}; // Let the first column be our colormap
Loop(ii, 2, nn)
{
 range rr = [%(wname$)]1!wcol(ii);
 rr = {0:1*(ii-1):10*(ii-1)};
 if(ii>2)
 {
  if(ii==3)
  {
   plotxy iy:=(2,3) plot:=201; // Plot the first scatter using col(3) and col(2)
   set %c -cse $(524389+ii-1); // Set Col(1) be color index
   set %c -cset 2; // Set color pattern to be colormapping
  }
  else {layer -i201 %(nameof(rr)$)}; // Add the rest to the layer
 }
 else
 {
  wks.col$(ii).type = 4; // Set col(2) to be X for plotting
 }; 
};
for(jj=1;jj<4;jj++)
{
 string pp$ = %(wname$)_%(char(jj+66)$);
 switch (jj)
 {
  case 1:
   get %(pp$) -cse t1; 
   get %(pp$) -cset t2;
   get %(pp$) -z t3;
   get %(pp$) -k t4; // Get the first plot's setting values
   break;
  case 2 3:
   set %(pp$) -cse $(t1+jj-1);
   set %(pp$) -cset t2;
   set %(pp$) -z $(jj*t3);
   set %(pp$) -k $(jj+t4-1); // Make some changes and apply to the other 2 plots
   break;
  default:
   break;
 };
};
rescale;

Example 10

Use Increment for symbol color and enable the usage of custom color list:

//Create new workbook, fill data and plot as scatter
newbook;
col(A) = data(1,12);
col(B) = col(A);
plotxy (1,2);
//Use Increment to define symbol color
set %c -ci 1;
//Enable the usage of custom color
set %c -cue 1;
//Define the color indices in the custom color list
set %c -cu 2 4 6 8;

See Also

Get (command)